Lotus Notes – kill all LN processes

Jeżeli program Lotus Notes zawiesi się w trakcie swej pracy, to zwykle nie pozwala na powtórne jego uruchomienie aż do kolejnego przelogowania użytkownika.
Problemem jest to, że działają inne procesy lotusowe. Rozwiązaniem jest ubicie wszystkich procesów, a mogą być różne, które mają wspólną ścieżkę uruchomienia: właściwość ExecutablePath procesu.
Poniżej prezentuję skrypt VBS, jedynie zmodyfikowany przeze mnie.
Po uruchomieniu pojawia się okno, w którym określamy maszynę. Jeżeli jest to lokalna maszyna, wystarczy wpisać znak kropki “.”.
Można także użyć adresu IP.
' ProcessKillRemote.vbs
' Sample VBScript kill process
' Author Guy Thomas http://computerperformance.co.uk/
' Modified by Ogre2000
' Version 1.0 - March 2011
' ------------------------ -------------------------------'
Option Explicit
Dim objWMIService, objProcess, colProcess
Dim strComputer, strProcessPath, strInput, strProcessList
'strProcessPath = "'C:\\winap\\ghost11\\%'"
strProcessPath = "'C:\\Program Files\\lotus\\notes\\%'"
' Input Box to get name of machine to run the process
Do
strComputer = (InputBox(" Podaj nazwę komputera" & vbCr & "Dla lokalnego komputera wpisz znak kropki .",_
"Computer Name"))
If strComputer <> "" Then
strInput = True
End if
Loop until strInput = True
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" _
& strComputer & "\root\cimv2")
Set colProcess = objWMIService.ExecQuery _
("Select * from Win32_Process Where ExecutablePath Like " & strProcessPath)
For Each objProcess in colProcess
objProcess.Terminate()
strProcessList = strProcessList & objProcess.Name & vbCr
Next
WSCript.Echo "You killed: " & strProcessList _
& " on " & strComputer
WScript.Quit
' End of WMI Example of a Kill Process

Gotowy skrypt do ściągnięcia tutaj: KillLotusNotes